# Copyright 1999-2020 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit systemd

DESCRIPTION="This is the proxy-daemon used by www-apps/guacamole"

HOMEPAGE="https://guacamole.apache.org/"
SRC_URI="http://mirrors.ircam.fr/pub/apache/guacamole/${PV}/source/guacamole-server-${PV}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="encode pulseaudio rdp ssh telnet vnc vorbis webp"
REQUIRED_USE="pulseaudio? ( vnc )"

RDEPEND="
	acct-group/guacamole
	acct-user/guacamole
	x11-libs/cairo
	media-libs/libpng:0=
	virtual/jpeg:0
	dev-libs/ossp-uuid
	app-text/ghostscript-gpl[-X]
	encode? ( media-video/ffmpeg )
	rdp? ( net-misc/freerdp )
	ssh? (
		net-libs/libssh2
		media-fonts/dejavu
		media-fonts/terminus-font
		x11-libs/pango )
	telnet?	(
		net-libs/libtelnet
		media-fonts/dejavu
		media-fonts/terminus-font
		x11-libs/pango )
	vnc? (
		net-libs/libvncserver[threads]
		pulseaudio? ( media-sound/pulseaudio ) )
	dev-libs/openssl:0=
	vorbis? ( media-libs/libvorbis )
	webp? ( media-libs/libwebp )
"
DEPEND="${RDEPEND}"

src_configure() {
	local myconf="--without-terminal --without-pango"

	if use ssh || use telnet; then
		myconf="--with-terminal --with-pango"
	fi

	econf ${myconf} \
		$(use_enable encode guacenc) \
		$(use_with ssh) \
		$(use_with rdp) \
		$(use_with vnc) \
		$(use_with pulseaudio pulse) \
		$(use_with vorbis) \
		$(use_with telnet) \
		$(use_with webp)
}

src_install() {
	default
	doinitd "${FILESDIR}/guacd"
	systemd_dounit "${FILESDIR}/guacd.service"
}