diff --git a/gnustep-libs/sope/Manifest b/gnustep-libs/sope/Manifest
new file mode 100644
index 0000000..10d8add
--- /dev/null
+++ b/gnustep-libs/sope/Manifest
@@ -0,0 +1,2 @@
+DIST sope-4.3.2.tar.gz 2203224 BLAKE2B a51f87ac5b6e2cbb432fa1a63f6240d9c3309d600d82040096f65140933d6ac2cc875dc3c0db88e1cd3ff944b3c85fd0155fde03ee27c894e3416c8aec9abedd SHA512 bbdd78d08af26f435f3faaaa89833b7f910443a971ccde34236af30bed54a6ff50b3bee52990902a74a40abf2050db53a198e208e10a515fd6353b0c9e6eb447
+EBUILD sope-4.3.2.ebuild 1406 BLAKE2B 0ed61de83f8f3547de75e0db042f90df64418ed439f1f8210eb18e1bfdddfb18339138f00a79e5e24309f6e01a07235494e1a3b165b7c665fa032ca3c6dbe41b SHA512 05fc57fbaab00f8ecf401e4e6507532587010eff047947bdad31ff7a0e074e70dd4ce88498147d8fb327037b53ee79bb90bbe8ba33e3fe502f2d622da89996ce
diff --git a/gnustep-libs/sope/sope-4.3.2.ebuild b/gnustep-libs/sope/sope-4.3.2.ebuild
new file mode 100644
index 0000000..a24c86a
--- /dev/null
+++ b/gnustep-libs/sope/sope-4.3.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnustep-2 vcs-snapshot
+
+DESCRIPTION="A set of frameworks forming a complete Web application server environment"
+HOMEPAGE="http://www.sogo.nu/"
+SRC_URI="https://github.com/inverse-inc/sope/archive/SOPE-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnutls ldap libressl mysql postgres +ssl +xml"
+
+RDEPEND="
+	sys-libs/zlib
+	ldap? ( net-nds/openldap )
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+	mysql? ( dev-db/mysql-connector-c:= )
+	postgres? ( dev-db/postgresql:= )
+	xml? ( dev-libs/libxml2:2 )
+"
+DEPEND="${RDEPEND}"
+
+pkg_pretend() {
+	if use ssl && use gnutls && use libressl ; then
+		ewarn "You have enabled both gnutls and libressl, but only"
+		ewarn "one provider can be active. Using gnutls!"
+	fi
+}
+
+src_configure() {
+	local ssl_provider
+	if use ssl ; then
+		if use gnutls ; then
+			ssl_provider=gnutls
+		else
+			ssl_provider=ssl
+		fi
+	else
+		ssl_provider=none
+	fi
+
+	egnustep_env
+
+	# Non-standard configure script
+	./configure \
+		--disable-strip \
+		$(use_enable debug) \
+		$(use_enable ldap openldap) \
+		$(use_enable mysql) \
+		$(use_enable postgres postgresql) \
+		$(use_enable xml) \
+		--with-ssl="${ssl_provider}" \
+		--with-gnustep || die "configure failed"
+}