From 279c814f35772f18604953e368f576705cd6e0de Mon Sep 17 00:00:00 2001
From: Joerg Deckert <joergd@bitquell.de>
Date: Sun, 23 Apr 2017 11:36:20 +0200
Subject: [PATCH] new: app-admin/keepassxc with yubikey support

---
 app-admin/keepassxc/Manifest              |  1 +
 app-admin/keepassxc/keepassxc-9999.ebuild | 63 +++++++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 app-admin/keepassxc/Manifest
 create mode 100644 app-admin/keepassxc/keepassxc-9999.ebuild

diff --git a/app-admin/keepassxc/Manifest b/app-admin/keepassxc/Manifest
new file mode 100644
index 0000000..dcfd8ef
--- /dev/null
+++ b/app-admin/keepassxc/Manifest
@@ -0,0 +1 @@
+EBUILD keepassxc-9999.ebuild 1304 SHA256 9a8028f4455ebca8736452c902b55aa089d41d24aa2935bca81807c220c79c82 SHA512 8a4828c48d3a21bd31e66511f07f8f4e9367b835f51adb71e118f1b2ae484ad5da8c9a169d165b2198410323ca63604d1233d66cb6e0e4163ee513612f8b16e5 WHIRLPOOL 8da49a882abcc965bcedbd14fb49d8b98256b516264fa0f1be71f77ef1c7d89cf5421db97ff352f9461cef54dc7a2d81f7f9cd4d64eadbde6fcdf41893e61cd6
diff --git a/app-admin/keepassxc/keepassxc-9999.ebuild b/app-admin/keepassxc/keepassxc-9999.ebuild
new file mode 100644
index 0000000..b237bab
--- /dev/null
+++ b/app-admin/keepassxc/keepassxc-9999.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+SCM=""
+[[ "${PV}" == 9999 ]] && SCM="git-r3"
+inherit cmake-utils ${SCM}
+unset SCM
+
+DESCRIPTION="KeePassXC - KeePass Cross-platform Community Edition"
+HOMEPAGE="https://github.com/keepassxreboot/keepassxc"
+
+if [[ "${PV}" != 9999 ]] ; then
+	SRC_URI="https://github.com/keepassxreboot/keepassxc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	EGIT_REPO_URI="https://github.com/keepassxreboot/${PN}"
+fi
+
+LICENSE="LGPL-2.1 GPL-2 GPL-3"
+SLOT="0"
+IUSE="autotype debug http test yubikey"
+
+RDEPEND="
+	dev-libs/libgcrypt:=
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	sys-libs/zlib
+	autotype? (
+		dev-qt/qtx11extras:5
+		x11-libs/libXi
+		x11-libs/libXtst
+	)
+	yubikey? ( sys-auth/libyubikey )
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qtconcurrent:5
+	test? ( dev-qt/qttest:5 )
+"
+
+src_prepare() {
+	 use test || \
+		sed -e "/^find_package(Qt5Test/d" -i CMakeLists.txt || die
+
+	 cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_GUI_TESTS=OFF
+		-DWITH_TESTS="$(usex test)"
+		-DWITH_XC_AUTOTYPE="$(usex autotype)"
+		-DWITH_XC_HTTP="$(usex http)"
+		-DWITH_XC_YUBIKEY="$(usex yubikey)"
+	)
+	cmake-utils_src_configure
+}