new: net-im/gajim

net-im/gajim/Manifest

@@ -0,0 +1,4 @@
+AUX disable-gspell-1.1.0.patch 679 BLAKE2B 1839fbb18127f155060895ffab92d2aa1b4fcab1fcf70c63fa19f729d34f92f47bfb2edfbf26c493ae11ed37817d3981d51996a1901ce8f8298163ebedf0e214 SHA512 cecfb65f055cb5fa7045ccce54fa919fe7051e593b475067ee1de201cc356bbaefd5d646e60feaa2ead83d1d36a9812565bbabc267d14c3df278613f52197910
+DIST gajim-gajim-1.1.2.tar.bz2 8207672 BLAKE2B 75d0b967c1470d32a21a120a61e01d19ed0dd9ca77752f22e2272aefc056ac3c0baa19989ae1762232355eabf69bc8bb501f974978601bcf2f6f052b0827ab00 SHA512 c1c1f68559b75dd54358d5cfe9024c672aa451d79633ad39e81879348692294ad8b4eb56d8c5c2dabdf2765aaed28100a5f2a48ea3937c00a968793c1144d3f3
+DIST gajim-plugins-1.1.2.tar.bz2 546043 BLAKE2B 82f8bac6201f0777538940ec6e203ded79853df4cf7b73528c4d46f0a9c460c42b9d5a09f6e078327660079e84cf272fe4570f86b7509c341165935c66b9016a SHA512 aa1ef9ea759021b878be1dfd2f38f098a8521e42e751007c3b4b17c12af86d936cb33d0593f7409f6596c8c035bc505ae61cbe7c8a3ffed297538b9cf78f8cd8
+EBUILD gajim-1.1.2.ebuild 3402 BLAKE2B 15b490c66ca9e7f7e81d5596e620aadafe537b01acc2127cb1794eba1e0714afc3abe9f74dc0c84cb29a94f97c06d598852527da7d8bbec7da651b3f2b3f82cd SHA512 f5f136a24488b645444f3c07983efbd3d34275d9a7a111e521df23de71e3d42c13724872e28480b35246d2de3d71dccbefcd6cecc66729a95f37f36b4d2adecb

net-im/gajim/files/disable-gspell-1.1.0.patch

@@ -0,0 +1,21 @@
+--- a/gajim/common/app.py	2018-11-06 23:57:20.088079001 +0100
++++ a/gajim/common/app.py	2018-11-06 23:58:36.638834033 +0100
+@@ -299,17 +299,7 @@
+         pass
+ 
+     # GSPELL
+-    try:
+-        gi.require_version('Gspell', '1')
+-        from gi.repository import Gspell
+-        langs = Gspell.language_get_available()
+-        for lang in langs:
+-            log('gajim').info('%s (%s) dict available',
+-                              lang.get_name(), lang.get_code())
+-        if langs:
+-            _dependencies['GSPELL'] = True
+-    except (ImportError, ValueError):
+-        pass
++    # [REMOVED BY EBUILD]
+ 
+     # Print results
+     for dep, val in _dependencies.items():

net-im/gajim/gajim-1.1.2.ebuild

@@ -0,0 +1,119 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLUGINS_COMMIT="54546918466c1236890264930791aee8e8b5e46c"
+
+KEYWORDS="amd64"
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="sqlite,xml"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 eapi7-ver gnome2-utils xdg-utils
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="https://www.gajim.org/"
+SRC_URI="https://dev.gajim.org/gajim/gajim/-/archive/gajim-${PV}/gajim-gajim-${PV}.tar.bz2
+         https://dev.gajim.org/gajim/gajim-plugins/-/archive/${PLUGINS_COMMIT}/gajim-plugins-${PLUGINS_COMMIT}.tar.bz2 -> gajim-plugins-${PV}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="gpg +crypt remote idle jingle keyring networkmanager upnp geoclue spell +webp rst omemo"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection[cairo,${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-arch/unzip
+	>=dev-util/intltool-0.40.1
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=dev-python/python-nbxmpp-0.6.9[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	>=dev-python/cssutils-1.0.2[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/precis-i18n[${PYTHON_USEDEP}]
+	dev-python/pycurl[${PYTHON_USEDEP}]
+	crypt? ( dev-python/pycryptodome[${PYTHON_USEDEP}] )
+	gpg? ( >=dev-python/python-gnupg-0.4.0[${PYTHON_USEDEP}] )
+	idle? ( x11-libs/libXScrnSaver )
+	remote? (
+		>=dev-python/dbus-python-1.2.0[${PYTHON_USEDEP}]
+		dev-libs/dbus-glib
+	)
+	rst? ( dev-python/docutils[${PYTHON_USEDEP}] )
+	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
+	jingle? (
+		net-libs/farstream:0.2[introspection]
+		media-libs/gstreamer:1.0[introspection]
+		media-libs/gst-plugins-base:1.0[introspection]
+		media-libs/gst-plugins-ugly:1.0
+	)
+	networkmanager? ( net-misc/networkmanager[introspection] )
+	upnp? ( net-libs/gupnp-igd[introspection] )
+	geoclue? ( app-misc/geoclue[introspection] )
+	spell? (
+		app-text/gspell[introspection]
+		app-text/hunspell
+	)
+	omemo? (
+		dev-python/python-axolotl[${PYTHON_USEDEP}]
+		dev-python/qrcode[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+	)
+	webp? ( dev-python/pillow[${PYTHON_USEDEP}] )
+"
+
+RESTRICT="test"
+
+S="${WORKDIR}/gajim-${P}"
+SP="${WORKDIR}/gajim-plugins-${PLUGINS_COMMIT}"
+
+src_prepare() {
+	default
+
+	use spell || eapply "${FILESDIR}/disable-gspell-1.1.0.patch"
+	use keyring || sed -i 's/keyring//' setup.cfg || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# Gajims build script compresses the man pages. Gentoo would like to
+	# compress them itself.
+	gunzip "${D}/usr/share/man/man1/gajim.1.gz"
+	gunzip "${D}/usr/share/man/man1/gajim-history-manager.1.gz"
+	gunzip "${D}/usr/share/man/man1/gajim-remote.1.gz"
+
+	# install plugins
+	python_moduleinto "${PN}/data/plugins"
+	python_domodule "${SP}/plugins_translations"
+	python_domodule "${SP}/url_image_preview"
+	if use omemo ; then
+		python_domodule "${SP}/omemo"
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+
+	ewarn "If you run into segfaults upon starting, you most likely ran into an issue"
+	ewarn "with app-text/enchant (bug 662484). Use USE=\"-spell\" to remedy."
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}