# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/assp/assp-1.9.8.13030.ebuild,v 1.3 2014/08/10 21:15:28 slyfox Exp $

EAPI=5

inherit eutils user

DESCRIPTION="Anti-Spam SMTP Proxy written in Perl"
HOMEPAGE="http://assp.sourceforge.net/"
MY_PN=ASSP_${PV}_${PR/r/}_install
SRC_URI="mirror://sourceforge/project/${PN}/ASSP%20V2%20multithreading/${PV}%20${PR/r/}/${MY_PN}.zip"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="amd64 x86"

IUSE="berkdb clamav ipv6 ldap mysql sasl snmp spf srs ssl syslog"

DEPEND="app-arch/unzip"

RDEPEND="dev-lang/perl[ithreads]
	dev-perl/libwww-perl
dev-perl/Archive-Zip
	dev-perl/BerkeleyDB
	dev-perl/Convert-TNEF
	dev-perl/Net-DNS
	dev-perl/File-ReadBackwards
	virtual/perl-IO-Compress
	dev-perl/Email-MIME
	dev-perl/Email-Send
	dev-perl/Email-Valid
	dev-perl/Lingua-Stem-Snowball
	dev-perl/Mail-DKIM
	dev-perl/mime-construct
	dev-perl/NetAddr-IP
	dev-perl/Net-CIDR-Lite
	dev-perl/Regexp-Optimizer
	dev-perl/Schedule-Cron
	dev-perl/Sys-CpuAffinity
	dev-perl/Sys-MemInfo
	dev-perl/Text-Unidecode
	dev-perl/Thread-State
	dev-perl/Tie-DBI
	dev-perl/Unicode-LineBreak
	dev-perl/Digest-SHA1
	virtual/perl-Digest-MD5
	virtual/perl-Time-HiRes
	clamav? ( dev-perl/File-Scan-ClamAV )
	ipv6? ( dev-perl/IO-Socket-INET6 )
	sasl? ( dev-perl/Authen-SASL )
	snmp? ( dev-perl/Net-SNMP )
	spf? ( dev-perl/Mail-SPF-Query
	       dev-perl/Mail-SPF )
	srs? ( dev-perl/Mail-SRS )
	ssl? ( dev-perl/IO-Socket-SSL
	       dev-perl/Net-SSLeay
	       dev-perl/Net-SMTP-SSL )
	berkdb? ( sys-libs/db:6.0 )
	mysql? ( virtual/mysql )
	syslog? ( virtual/perl-Sys-Syslog )
	ldap? ( dev-perl/perl-ldap )"

S=${WORKDIR}/${PN}

pkg_setup() {
	enewgroup assp
	enewuser assp -1 -1 /dev/null assp
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	mkdir quarantine
}

src_install() {
	dodir /opt/assp
	cp -r . ${D}/opt/assp
	fowners assp:assp -R /opt/assp
	fperms 755 /opt/assp/assp-monitor.pl /opt/assp/assp.pl /opt/assp/assp_pop3.pl

	# Install the init.d script to listen
	newinitd "${FILESDIR}/asspd.init" asspd
}

pkg_postinst() {
	elog
	elog "To configure ASSP, start /etc/init.d/asspd then point"
	elog "your browser to http://localhost:55555"
	elog "Username: admin  Password: nospam4me (CHANGE ASAP!)"
	elog
	elog "File permissions have been set to use assp:assp"
	elog "with mode 770 on directories.  When you configure"
	elog "ASSP, make sure and use the user assp."
	elog
	elog "Don't change any path related options."
	elog
	elog "See the on-line docs for a complete tutorial."
	elog "http://assp.sourceforge.net/docs.html"
	elog
}