# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/assp/assp-1.9.8.13030.ebuild,v 1.3 2014/08/10 21:15:28 slyfox Exp $

EAPI=5

inherit eutils user

VERSION_PLUGIN_AFC=3.14
VERSION_PLUGIN_ARC=2.06
VERSION_PLUGIN_DCC=2.01
VERSION_PLUGIN_OCR=2.20
VERSION_PLUGIN_RAZOR=1.09

DESCRIPTION="Anti-Spam SMTP Proxy written in Perl"
HOMEPAGE="http://assp.sourceforge.net/"
MY_PN=ASSP_${PV}_${PR/r/}_install
SRC_URI="mirror://sourceforge/project/${PN}/ASSP%20V2%20multithreading/${PV}%20${PR/r/}/${MY_PN}.zip
         afc? ( mirror://sourceforge/project/${PN}/ASSP%20V2%20multithreading/Plugins/ASSP_AFC%20-%20AttachmentFullCheck%20Plugin/ASSP_AFC_${VERSION_PLUGIN_AFC}.zip )
         arc? ( mirror://sourceforge/project/${PN}/ASSP%20V2%20multithreading/Plugins/ASSP_ARC%20-%20Archive%20Plugin/ASSP_ARC_${VERSION_PLUGIN_ARC}.zip )
         dcc? ( mirror://sourceforge/project/${PN}/ASSP%20V2%20multithreading/Plugins/ASSP_DCC%20-%20DCC%20Plugin/ASSP_DCC_${VERSION_PLUGIN_DCC}.zip )
         ocr? ( mirror://sourceforge/project/${PN}/ASSP%20V2%20multithreading/Plugins/ASSP_OCR%20-%20OCR%20Plugin/ASSP_OCR_${VERSION_PLUGIN_OCR}.zip )
         razor? ( mirror://sourceforge/project/${PN}/ASSP%20V2%20multithreading/Plugins/ASSP_Razor%20-%20Razor2%20Plugin%20for%20ASSP/ASSP_Razor_${VERSION_PLUGIN_RAZOR}.zip )"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="amd64 x86"

IUSE="afc arc berkdb clamav dcc ipv6 ldap mysql ocr odbc postgres razor sasl snmp spf srs ssl syslog"

DEPEND="app-arch/unzip"

RDEPEND="dev-lang/perl[ithreads]
	dev-perl/libwww-perl
	dev-perl/Archive-Extract
	dev-perl/Archive-Zip
	dev-perl/CAM-PDF
	dev-perl/Convert-Scalar
	dev-perl/Convert-TNEF
	dev-perl/Crypt-CBC
	dev-perl/Crypt-GOST
	dev-perl/Crypt-OpenSSL-AES
	dev-perl/Crypt-RC4
	dev-perl/Crypt-SMIME
	dev-perl/DBD-Sprite
	dev-perl/Devel-Size
	dev-perl/Digest-SHA1
	virtual/perl-Digest-MD5
	dev-perl/Email-MIME
	dev-perl/Email-Send
	dev-perl/Email-Valid
	dev-perl/File-chmod
	dev-perl/File-Find-Rule
	dev-perl/File-ReadBackwards
	dev-perl/File-Slurp
	dev-perl/File-Type
	dev-perl/File-Which
	virtual/perl-IO-Compress
	dev-perl/IO-Compress-Lzma
	dev-perl/IO-stringy
	dev-perl/LEOCHARRE-Class2
	dev-perl/LEOCHARRE-CLI
	dev-perl/LEOCHARRE-DEBUG
	dev-perl/Lingua-Identify
	dev-perl/Lingua-Stem-Snowball
	dev-perl/Lingua-StopWords
	dev-perl/Linux-usermod
	dev-perl/Mail-DKIM
	dev-perl/mime-construct
	dev-perl/NetAddr-IP
	dev-perl/Net-CIDR-Lite
	dev-perl/Net-DNS
	dev-perl/Net-IP-Match-Regexp
	dev-perl/Net-SenderBase
	dev-perl/Net-Syslog
	dev-perl/Number-Compare
	dev-perl/PDF-API2
	dev-perl/PDF-GetImages
	dev-perl/PDF-Burst
	dev-perl/Regexp-Optimizer
	dev-perl/Schedule-Cron
	dev-perl/Smart-Comments
	dev-perl/Sys-CpuAffinity
	dev-perl/Sys-MemInfo
	dev-perl/Text-Glob
	dev-perl/Text-PDF
	dev-perl/Text-Unidecode
	dev-perl/Thread-State
	dev-perl/Tie-DBI
	virtual/perl-Time-HiRes
	dev-perl/Unicode-LineBreak
	dev-perl/YAML
	clamav? ( dev-perl/File-Scan-ClamAV )
	ipv6? ( dev-perl/IO-Socket-INET6 )
	sasl? ( dev-perl/Authen-SASL )
	snmp? ( dev-perl/Net-SNMP )
	spf? ( dev-perl/Mail-SPF-Query
	       dev-perl/Mail-SPF )
	srs? ( dev-perl/Mail-SRS )
	ocr? ( dev-perl/Image-OCR-Tesseract
	       dev-perl/PDF-OCR
	       dev-perl/PDF-OCR2 )
	ssl? ( dev-perl/IO-Socket-SSL
	       dev-perl/Net-SSLeay
	       dev-perl/Net-SMTP-SSL )
	berkdb? ( sys-libs/db:6.0 
	          dev-perl/BerkeleyDB )
	mysql? ( dev-perl/DBD-mysql )
	odbc? ( dev-perl/DBD-ODBC )
	postgres? ( dev-perl/DBD-PgPP )
	syslog? ( virtual/perl-Sys-Syslog )
	ldap? ( dev-perl/perl-ldap
	        dev-perl/DBD-LDAP )"

S=${WORKDIR}/${PN}

pkg_setup() {
	enewgroup assp
	enewuser assp -1 -1 /dev/null assp
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	mkdir quarantine
	if use afc; then
	    mv "${WORKDIR}"/ASSP_AFC.pm Plugins/ || die
	fi
	if use arc; then
	    mv "${WORKDIR}"/ASSP_ARC.pm Plugins/ || die
	fi
	if use dcc; then
	    mv "${WORKDIR}"/ASSP_DCC.pm Plugins/ || die
	fi
	if use ocr; then
	    mv "${WORKDIR}"/ASSP_OCR.pm Plugins/ || die
	fi
	if use razor; then
	    mv "${WORKDIR}"/ASSP_Razor.pm Plugins/ || die
	fi

}

src_install() {
	dodir /opt/assp
	cp -r . ${D}/opt/assp
	fowners assp:assp -R /opt/assp
	fperms 755 /opt/assp/assp-monitor.pl /opt/assp/assp.pl /opt/assp/assp_pop3.pl

	# Install the init.d script to listen
	newinitd "${FILESDIR}/asspd.init" asspd
}

pkg_postinst() {
	elog
	elog "To configure ASSP, start /etc/init.d/asspd then point"
	elog "your browser to http://localhost:55555"
	elog "Username: admin  Password: nospam4me (CHANGE ASAP!)"
	elog
	elog "File permissions have been set to use assp:assp"
	elog "with mode 770 on directories.  When you configure"
	elog "ASSP, make sure and use the user assp."
	elog
	elog "Don't change any path related options."
	elog
	elog "See the on-line docs for a complete tutorial."
	elog "http://assp.sourceforge.net/docs.html"
	elog
}